/* Comparing Proportions  
Immunization Rates for three types of payor are compared in a
Retrospective Study in which all patients treated in last year are included.
KEY POINT: a child was immunized on time or was not; ANOM is alternative to 
Chi-Square table test.*/
title;
data Immune1;
   input payor$ immunized total;
datalines;
PPO 170 217
HMO 168 335
Medicaid  188 219


;
run;
symbol1 v=dot;

   title 'Proportion Immunized on Time by Payor/Provider';
   
   proc anom data=Immune1;
      pchart immunized*payor / groupn = total alpha=.01  wneedles = .5
			outtable = IMMtable1;
	label immunized = 'Proportion Immunized';
   run;
proc print data = IMMtable1;
run;
/* Comparing Proportions  
Immunization Rates for 7 practices are compared
Retrospective Study; all patients treated in last year are included.
KEY POINT: a child was immunized on time or was not*/
title;
data Immune2;
   input practice$ immunized total;
datalines;
1 170 217
2 168 335
3  188 219
4 77 103
5 66 88
6 345 398
7 25 40


;
run;
symbol1 v=dot;

   title 'Proportion Immunized on Time by Practice';
   
   proc anom data=Immune2;
      pchart immunized*practice / groupn = total alpha=.05  wneedles = .5
			outtable = IMMtable2;
	label immunized = 'Proportion Immunized';
   run;
proc print data = IMMtable2;
run;
/* Comparing Rates  
Three types of provider are compared with respect to the number of primary care 
office visits.  Unit of opportunity is patient years.  For example, a patient in 
the system for six months = 0.5 patient years.
KEY POINT: A patient may have 0,1,2,3,... visits to MD.  Model these as Poisson.*/

data Pvisits1;
   input payor$ visits patientYEARS;
datalines;
PPO 170 120
HMO 168 100
Medicaid  130 144


;
run;
symbol1 v=dot;

   title 'MD Visits by Payor';
   
   proc anom data=Pvisits1;
      uchart visits*payor / groupn = patientYEARS alpha=.05  wneedles = .5
			outtable = VISITtable1;
	label visits= 'Visits per Patient per Year';
   run;
proc print data = VISITtable1;
run;
/* Comparing rates
Four sunscreens are compared (one placebo) in a blinded study.
280 subjects were enrolled in the study (70 with each treatemnt).  
At the end of two years (dropouts have created imbalance in sample sizes) the 
number of cancerous/precancerous lesions are counteded.
KEY POINT: a subject may have 0,1,2,3,... lesions. So, for example, with screen1
there were 11 lesions on the 44 (remaining) subjects. Perhaps subject one
had three of these?*/


data Clesions1;
   input screen$ lesions patients;
datalines;
Screen1 11 44
Screen2 12 50
Screen3  8 58
Placebo  26 60


;
run;
symbol1 v=dot;

   title 'Cancerous Lesions';
   
   proc anom data=Clesions1;
      uchart lesions*screen / groupn = patients alpha=.05  wneedles = .5
			outtable = Lesionstable1;
	label lesions = 'Lesions per Patient per Year';
   run;
proc print data = Lesionstable1;
run;
/* Averages --- Interval Data  
Study effects of a drug on hemoglobin levels.  20 subjects in study.  
10 had interferron and 10 had radiation.  Each group of 10 subjects 
randomly divided into drug versus no drug
groups.  Hemoglobin levels measured at 60 days.  
Dropouts (unrelated to treatment) created the imbalance.
KEY POINT: the data are interval/continuous measurements that might reasonably 
be modeled as normally distributed; the ANOM is an alternative to ANOVA.*/
data HEMO1;
   input treatment$ HEMO;
datalines;


INT_NO_DRUG  11
INT_NO_DRUG  9
INT_NO_DRUG 11 
RAD_NO_DRUG 8
RAD_NO_DRUG  12
RAD_NO_DRUG 10
RAD_NO_DRUG 9
RAD_NO_DRUG 10
INT_DRUG  14
INT_DRUG  13
INT_DRUG  15
INT_DRUG  12
INT_DRUG  11

RAD_DRUG  17
RAD_DRUG  12
RAD_DRUG  15
RAD_DRUG  16




;
run;
symbol1 v=dot;

   title 'Hemoglobin Levels at 60 days';
   
   proc anom data=hemo1;
      xchart hemo*treatment / alpha=.05  wneedles = .5
			outtable = Hemotable1;
	label hemo = 'Average Hemoglobin Level';
   run;
proc print data = Hemotable1;
run;

/* Averages --- Interval Data  
Drug Study on pain palliatives.  Three drugs (A,B,C) each at two dosage levels.
Measure the number of pair-free-hours. Randomized prospective study.  Blinded.
Dropouts (unrelated to treatment) created the imbalance.
KEY POINT: the data are interval/continuous measurements that might reasonably 
be modeled as normally distributed; the ANOM is an alternative to ANOVA.*/

data HwoPain1;
   input Drug$ Hours;
datalines;


A10mg  11
A10mg  9
A10mg 11 
A10mg 8
A20mg  12
A20mg 10
A20mg 9
A20mg 10
B10mg  14
B10mg  13
B10mg  15
B10mg 12
B10mg  11

B20mg  17
B20mg  12
B20mg  15
B20mg  16

C10mg 8
C10mg 9
C10mg 6
C10mg 10
C10mg 11

C20mg 12
C20mg 14
C20mg 11
C20mg 10
C20mg 15





;
run;
symbol1 v=dot;

   title 'Hours Without Pain by Drug';
   
   proc anom data=HwoPain1;
      xchart hours*drug / alpha=.05  wneedles = .5
			outtable = Hpain1;
	label hours = 'Average Hours Without Pain';
   run;
proc print data = Hpain1;
run;

quit;