/* Comparing Proportions  
Immunization Rates for three types of payor are compared in a
Retrospective Study in which 200 patients from each payor group
are selected.
KEY POINT: a child was immunized on time or was not; ANOM is alternative to 
Chi-Square table test.*/
title;
data Immune1;
   input payor$ immunized total;
datalines;
PPO 170 200
HMO 168 200
Medicaid  188 200


;
run;
symbol1 v=dot;

   title 'Proportion Immunized on Time by Payor/Provider';
   
   proc anom data=Immune1;
      pchart immunized*payor / groupn = total alpha=.01 nolegend wneedles = .5
			outtable = IMMtable1;
	label immunized = 'Proportion Immunized';
   run;
proc print data = IMMtable1;
run;
/* Comparing Rates  
Three types of provider are compared with respect to the number of primary care 
office visits.  Unit of opportunity is patient years.  For example, a patient in 
the system for six months = 0.5 patient years.  100 patient years are selected from
each type of practice.
KEY POINT: A patient may have 0,1,2,3,... visits to MD.  Model these as Poisson.*/

data Pvisits1;
   input payor$ visits patientYEARS;
datalines;
PPO 170 100
HMO 168 100
Medicaid  120 100


;
run;
symbol1 v=dot;

   title 'MD Visits by Payor';
   
   proc anom data=Pvisits1;
      uchart visits*payor / groupn = patientYEARS alpha=.05 nolegend wneedles = .5
			outtable = VISITtable1;
	label visits= 'Visits per Patient per Year';
   run;
proc print data = VISITtable1;
run;
/* Comparing rates
Four sunscreens are compared (one placebo) in a blinded study.
200 subjects were enrolled in the study (50 with each treatemnt).  
At the end of two years  the 
number of cancerous/precancerous lesions are counteded.
KEY POINT: a subject may have 0,1,2,3,... lesions. So, for example, with screen1
there were 11 lesions on the 44 (remaining) subjects. Perhaps subject one
had three of these?*/

data Clesions1;
   input screen$ lesions patients;
datalines;
Screen1 11 50
Screen2 12 50
Screen3  8 50
Placebo  26 50


;
run;
symbol1 v=dot;

   title 'Cancerous Lesions';
   
   proc anom data=Clesions1;
      uchart lesions*screen / groupn = patients alpha=.05 nolegend wneedles = .5
			outtable = Lesionstable1;
	label lesions = 'Lesions per Patient per Year';
   run;
proc print data = Lesionstable1;
run;
/* Averages --- Interval Data 
Study effects of a drug on hemoglobin levels.  20 subjects in study.  
10 had interferron and 10 had radiation.  Each group of 10 subjects 
randomly divided into drug versus no drug
groups.  Hemoglobin levels measured at 60 days.  

KEY POINT: the data are interval/continuous measurements that might reasonably 
be modeled as normally distributed; the ANOM is an alternative to ANOVA.*/
data HEMO1;
   input treatment$ HEMO;
datalines;
INT_NO_DRUG 10
INT_NO_DRUG  9
INT_NO_DRUG  11
INT_NO_DRUG  9
INT_NO_DRUG 11 
RAD_NO_DRUG 8
RAD_NO_DRUG  12
RAD_NO_DRUG 10
RAD_NO_DRUG 9
RAD_NO_DRUG 10
INT_DRUG  14
INT_DRUG  13
INT_DRUG  15
INT_DRUG  12
INT_DRUG  11
RAD_DRUG  16
RAD_DRUG  17
RAD_DRUG  12
RAD_DRUG  15
RAD_DRUG  16




;
run;
symbol1 v=dot;

   title 'Hemoglobin Levels at 60 days';
   
   proc anom data=hemo1;
      xchart hemo*treatment / alpha=.05 nolegend wneedles = .5
			outtable = Hemotable1;
	label hemo = 'Average Hemoglobin Level';
   run;
proc print data = Hemotable1;
run;

quit;